<% 
'----------------------------------------------------------
'使用XMLHTTP生成静态首页的代码
'Curl 为你的首页地址，确保你的空间支持FSO
'-----------------------------------------------------------
  
dim read,Curl,content
'下面这个地址就是你的首页了。
Curl="http://www.sinmeng.net/"
read=getHTTPPage(Curl)
  
if read<>"" then
  content=read
  call makeindex()
end if
  
sub makeindex()
  Set Fso = Server.CreateObject("Scripting.FileSystemObject")
'下面这个index.html就是生成的文件名
  Filen=Server.MapPath("index.html")
  Set Site_Config=FSO.CreateTextFile(Filen,true, False)
  Site_Config.Write content
  Site_Config.Close
  Set Fso = Nothing
  Response.Write("<script>alert('已经成功生成首页！');window.location.href='http://www.sinmeng.net/'</script>")
end sub
  
Function getHTTPPage(url) 
  dim http 
  set http=Server.createobject("Microsoft.XMLHTTP") 
  Http.open "GET",url,false
  Http.send() 
  if Http.readystate<>4 then
    exit function
  end if
  getHTTPPage=bytesToBSTR(Http.responseBody,"GB2312")
  set http=nothing
  if err.number<>0 then err.Clear 
End function
  
Function BytesToBstr(body,Cset) 
  dim objstream
  set objstream = Server.CreateObject("adodb.stream")
  objstream.Type = 1
  objstream.Mode =3
  objstream.Open
  objstream.Write body
  objstream.Position = 0
  objstream.Type = 2
  objstream.Charset = Cset
  BytesToBstr = objstream.ReadText 
  objstream.Close
  set objstream = nothing
End Function
%>